quickref.lisp

(defpackage quickref
  (:use :cl :split-sequence)
  (:import-from :alexandria
   :starts-with-subseq)
  (:export :print-primary-systems
	   :get-primary-system-name
	   :build-texis
	   :build-index
	   :build-releases
	   :refresh))

(in-package :quickref)

(defun remove-cl-prefix (name)
  (if (starts-with-subseq "cl-" name)
      (subseq name 3)
      name))

(defun get-release-name (system)
  (ql-dist:name (ql-dist:release system)))

(defun get-provided-systems (release)
  (let* ((all-provided-systems (ql-dist:provided-systems t))
	 (first-system-found (find release all-provided-systems
				   :key #'get-release-name
				   :test #'string=)))
    (unless first-system-found
      (error "Release not found"))
    (ql-dist:provided-systems (ql-dist:release first-system-found))))

(defun get-trimmed-system-name (system)
  (remove-cl-prefix (ql-dist:name system)))

(defun get-primary-system-name (release)
  (let ((project (remove-cl-prefix release))
	(provided-systems (get-provided-systems release)))
    (ql-dist:name
     (or (find project provided-systems
	       :key #'get-trimmed-system-name
	       :test #'string=
	       :from-end t)
	 (car (last provided-systems))))))

(defun print-primary-systems ()
  (dolist (release (ql-dist:provided-releases t))
    (print (get-primary-system-name (ql-dist:name release)))))

(defun build-releases ()
  (qlmapper:map-releases
   (concatenate 'string
		(namestring (asdf:system-source-directory "quickref"))
		"map-declt.lisp")))

(defun uninstall-releases ()
  (dolist (release (ql-dist:provided-releases t))
    (ql-dist:uninstall release)))

(defun refresh (makeinfo-path)
  (uninstall-releases)
  (ql:update-all-dists :prompt nil)
  (ql:update-client :prompt nil)
  (build-releases)
  (build-texis makeinfo-path)
  (build-index))